//---------------------------------------------------
// A fizikai szimulációhoz be kell kapcsolni
// a fizika módot, és előrre be kell állítani
// a gravitáció irányát. 

gravitáció(0, -10, 0)
fizika.start

//-------------------------------------------------
// innentől kezdeve a tégla, gömb, henger 
// testekre hatással lesz a gravitáció!

texture(matematika/p_07.jpg)
for(n,1,50)

     hely.véletlen(0,10,0, 30, 0, 30)
     forgás.véletlen()
     méret.véletlen()
     tégla(1)
  
next(n)

camera(KAM, 16.79, 31.62, 51.23, 0, 0, 0)


 

Testek elhelyezése a virtuális térben

Ez pontosan úgy történik, mint a normál webglbasic kódolásnál. Használható a szín, a textúra, a hely, a forgás parancs. Geometriából csak a gömb, henger, téglatest! A példában 50 db téglatestet generálok, és a lefelé mutató gravitációs vektor miatt mind lefele zuhan.

//---------------------------------------------------
// A fizikai szimulációhoz be kell kapcsolni
// a fizika módot, és előrre be kell állítani
// a gravitáció irányát. 

gravitáció(0, -10, 0)
fizika.start

//-------------------------------------------------
// innentől kezdeve a tégla, gömb, henger 
// testekre hatással lesz a gravitáció!

texture(matematika/p_07.jpg)
for(n,1,50)

  hely.véletlen(0,10,0, 10, 0, 10)
  forgás.véletlen()
  méret.véletlen()
  tégla(1)
  
next(n)

//----------------------------------------------
// padló nem mozog


test.mozgás(ki)


texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)


camera(KAM, 16.79, 31.62, 51.23, 0, 0, 0)


 

Test mozgása

Alapesetben minden test elmozdulhat a gravitáció miatt. Ez kikapcsolható a test.mozgás(ki), vagy test.mozgás(off) paranccsal.

A példában egy nagyobb lapos téglatestből készítettem padlót. Kikapcsolva a mozgását, a lezuhanó téglák visszapattannak róla.

beállítások(koordináták,ki)
anyag
gravitáció(0, -10, 0)
fizika.start


//-----------------------------------
// A testeknek egyéni nevet adtam

texture(planet/pl031.png)
hely(-12,2,0)
gömb(4)  DEF   PLANET1


texture(planet/pl015.png)
hely( 12,2,0)
gömb(4)  DEF   PLANET2


//-----------------------------------
// mindkét test kap egy sebességvektort

test.sebesség(PLANET1,  20, 0,0)
test.sebesség(PLANET2, -5, 0 ,0)



//----------------------------------------------
// a padló nem mozog


test.mozgás(ki)


texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)


camera(START, 11.59, 24.38, 34.4, -0.13, 2.3, -1.38)
kam


 

Sebességvektor

Minden testnek adható egy kezdeti sebességvektor, ami a jelenet betöltődésekor aktiválódik.

Fontos, hogy a testnek legyen egyéni neve, amit a DEF kulcsszóval lehet megadni. Ezután tudunk hivatkozni az adott testre a test.sebesség(NÉV, x,y,z) paranccsal.

A példában a PLANET1, és a PLANET2 gömbök azonos méretűek, de az első 4x nagyobb sebességet kap, mint a második. Ezért szinte lelöki a jobboldali gömböt a padlóról.

beállítások(koordináták,ki)
anyag
gravitáció(0, -10, 0)
fizika.start


//-----------------------------------
// A testeknek egyéni nevet adtam

texture(planet/pl031.png)
hely(-12, 2, 0)
test.sűrűség(1)
test.rugalmasság(0.8)
gömb(4)  DEF   PLANET1


texture(planet/pl015.png)
hely( 12, 2, 0)
test.sűrűség(1)
test.rugalmasság(1.2)
gömb(4)  DEF   PLANET2



//-----------------------------------
// mindkét test kap egy sebességvektort

test.sebesség(PLANET1,  10, 0, 0)
test.sebesség(PLANET2, -10, 0 ,0)





//----------------------------------------------
// Padló + 2 d fal az ütközéshez


test.mozgás(ki)
test.rugalmasság(1)
texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)

texture(matematika/p_22.jpg,10,2)
hely(-25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(25,3,0)
tégla( 0.1, 6, 50)


camera(Start, 15.14, 32.77, 63.15, -2.13, 0.15, 0.29)
kam




 

RUGALMASSÁG

A test rugalmassága meghatározza, hogy ütközéskor mennyi energiát veszít. Az 1-nél kisebb rugalmassági tényező esetén fokozatosan elveszti az összes mozgási energiáját, és egy idő múlva a sebessége nulla lesz. A szimuláció megengedi 1-nél nagyobb rugalmasság használatát, ami azzal jár, hogy minden ütközésnél nagyobb lesz az energiája.

A példában a falak 1-es rugalmassággal rendelkeznek, a baloldali gömb 0.8-as, a jobboldali 1.2-es értékű.

beállítások(koordináták,ki)
anyag
gravitáció(0, -10, 0)
fizika.start


//-----------------------------------
// SURGLÓDÁS 0.7

texture(matematika/p_piros.gif,2,2)
hely(-15, 10, 10)
forgás(0,0,-30)
test.sűrűség(1)
test.surlódás(0.7)
test.rugalmasság(0.5)
tégla(4,4,4) 


//-----------------------------------
// SURGLÓDÁS 0.6

texture(matematika/p_piros.gif,2,2)
hely(-15, 10, 0)
forgás(0,0,-30)
test.sűrűség(1)
test.surlódás(0.6)
test.rugalmasság(0.5)
tégla(4,4,4) 


//-----------------------------------
// SURGLÓDÁS 0.3

texture(matematika/p_piros.gif,2,2)
hely(-15, 10, -10)
forgás(0,0,-30)
test.sűrűség(1)
test.surlódás(0.3)
test.rugalmasság(0.5)
tégla(4,4,4) 



//----------------------------------------------
// Padló + 2 d fal az ütközéshez


test.mozgás(ki)
test.rugalmasság(0.8)
test.surlódás(0.5)

texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)

texture(matematika/p_22.jpg,10,2)
hely(-25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(25,3,0)
tégla( 0.1, 6, 50)


texture(matematika/p_09.jpg,10,20)
//--------------------------------------
// lejtő

test.surlódás(0.5)
hely(-10,5,0)
forgás(0,0,-30)
tégla(20,0.1,40)


camera(KAM, 17.53, 19.58, 41.44, -10.67, 3.03, 2.43)
kam





 

SÚRLÓDÁS

A súrlódási tényező 0..1 közötti szám. Minél kisebb, annál jobban „csúszik” a test egy másik testen. A példában a lejtő 0.5-es értékű, a kockák pedig 0.3, 0.6, 0.7 értékűek.

beállítások(koordináták,ki)
anyag
gravitáció(0, -10, 0)
fizika.start


//-----------------------------------

texture(matematika/p_piros.gif,4,4)
hely(0, 6, 0)
forgás(0,0,0)
test.surlódás(0)
test.rugalmasság(1)
gömb(4)  DEF  LABDA

test.sebesség(LABDA, 10,0,5)
test.perdület(LABDA, 0, 10, 0)


//----------------------------------------------
// Padló + 2 d fal az ütközéshez


test.mozgás(ki)
test.rugalmasság(0.8)
test.surlódás(0)

texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)

texture(matematika/p_22.jpg,10,2)
hely(-25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(0,3,25)
tégla( 50, 6, 0.1)

texture(matematika/p_22.jpg,10,2)
hely(0,3,-25)
tégla( 50, 6, 0.1)


camera(START, 21.69, 37.32, 59.44, -3.44, -1.49, -1.79)
kam

 

PERDÜLET

A sebességvektorhoz hasonlóan működik. A jelenet betöltésekor kaphat a test forgási energiát. A rugalmasság, és a súrlódási tényezők csökkenthetik majd a perdületet.

A példában viszont 0-ra állítottam a sutlódást, és a rugalmasság is 1. Ezért semmi sem csökkeni a perdületet, és a sebességet.

camera(START KAMERA, 21.69, 37.32, 59.44, -3.44, -1.49, -1.79)


beállítások(koordináták,ki)
anyag
gravitáció(0, -10, 0)
fizika.start


//-----------------------------------

texture(matematika/p_piros.gif,4,4)
hely(-10, 10, 0)
forgás(0,0,0)
test.surlódás(0.5)
test.rugalmasság(0.5)
gömb(4)  DEF  LABDA

test.sebesség(LABDA, 10,0,5)
test.perdület(LABDA, 0, 10, 0)


//-------------------------------------------------
// 

feladat(Alaphelyzet - Gyors)
   feladat.hely(LABDA, -10,10,0)
   feladat.sebesség.x(LABDA, 10)
   feladat.sebesség.y(LABDA, 0)
   feladat.sebesség.z(LABDA, 5)

   feladat.perdület.x(LABDA, 0)
   feladat.perdület.y(LABDA, 10)
   feladat.perdület.z(LABDA, 0)
feladat.vége


feladat(Alaphelyzet - Lassú)
   feladat.hely(LABDA, -10,10,0)
   feladat.sebesség.x(LABDA, 3)
   feladat.sebesség.y(LABDA, 0)
   feladat.sebesség.z(LABDA, 1)

   feladat.perdület.x(LABDA, 0)
   feladat.perdület.y(LABDA, 1)
   feladat.perdület.z(LABDA, 0)
feladat.vége


//----------------------------------------------
// Padló + 2 d fal az ütközéshez


test.mozgás(ki)
test.rugalmasság(0.8)
test.surlódás(0.5)

texture(matematika/p_22.jpg,10,10)
hely(0,0,0)
forgás(0,0,0)
méret(1,1,1)
tégla(50, 0.1, 50)

texture(matematika/p_22.jpg,10,2)
hely(-25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(25,3,0)
tégla( 0.1, 6, 50)

texture(matematika/p_22.jpg,10,2)
hely(0,3,25)
tégla( 50, 6, 0.1)

texture(matematika/p_22.jpg,10,2)
hely(0,3,-25)
tégla( 50, 6, 0.1)


 

FELADATOK

Feladatnak neveztem el azt az interaktív lehetőséget, amikor a felhasználó egy gombra kattintva beleavatkozhat a test fizikai jellemzőibe.

A feladat utasítás argumentumában kell a gomb nevét megadni: feladat(Alaphelyzet - Gyors)

Ezután kell felsorolni a feladat egyes összetevőit:

• hely megváltoztatása: feladat.hely(LABDA, -10,10,0)
• sebesség módosítása: feladat.sebesség.x(LABDA, 10)
• perdület módosítása: feladat.perdület.x(LABDA, 0)

Végül le kell zárni az adott feladatot: feladat.vége